不少用戶稱自己按提示重啟計算機(jī)后仍然無效，還是無法運(yùn)行騰訊手游助手，該怎么辦呢？出現(xiàn)這樣的問題是因為電腦中含有bd0001.sys和bd0004.sys的系統(tǒng)驅(qū)動，驅(qū)動會阻礙助手導(dǎo)致助手無法正常啟動。針對這一問題大家可以使用本文中winwin7給大家分享的方法來解決。
騰訊手游助手：檢測到不兼容百度bd0001 的解決方法：
1、新建一個文本文檔，打開后將下面代碼復(fù)制進(jìn)去：
rem 請用出現(xiàn)問題的電腦打開該文件！
::::::::::::::::::::::::::::::::::::::::::::
:: Elevate.cmd - Version 4
:: Automatically check & get admin rights
:: see "https://stackoverflow.com/a/12264592/1016343" for description
::::::::::::::::::::::::::::::::::::::::::::
@echo off
CLS
ECHO.
ECHO =============================
ECHO 管理員模式啟動中，請在彈出的窗口欄里選擇“是”
ECHO 部分殺毒軟件會阻攔（比如360），請選擇“允許”
ECHO =============================
:init
setlocal DisableDelayedExpansion
set cmdInvoke=1
set winSysFolder=System32
set "batchPath=%~0"
for %%k in (%0) do set batchName=%%~nk
set "vbsGetPrivileges=%temp%\OEgetPriv_%batchName%.vbs"
setlocal EnableDelayedExpansion
:checkPrivileges
NET FILE 1>NUL 2>NUL
if '%errorlevel%' == '0' ( goto gotPrivileges ) else ( goto getPrivileges )
:getPrivileges
if '%1'=='ELEV' (echo ELEV & shift /1 & goto gotPrivileges)
ECHO.
ECHO **************************************
ECHO 提升管理員權(quán)限中...
ECHO **************************************
ECHO Set UAC = CreateObject^("Shell.Application"^) > "%vbsGetPrivileges%"
ECHO args = "ELEV " >> "%vbsGetPrivileges%"
ECHO For Each strArg in WScript.Arguments >> "%vbsGetPrivileges%"
ECHO args = args ^& strArg ^& " " >> "%vbsGetPrivileges%"
ECHO Next >> "%vbsGetPrivileges%"
if '%cmdInvoke%'=='1' goto InvokeCmd
ECHO UAC.ShellExecute "!batchPath!", args, "", "runas", 1 >> "%vbsGetPrivileges%"
goto ExecElevation
:InvokeCmd
ECHO args = "/c """ + "!batchPath!" + """ " + args >> "%vbsGetPrivileges%"
ECHO UAC.ShellExecute "%SystemRoot%\%winSysFolder%\cmd.exe", args, "", "runas", 1 >> "%vbsGetPrivileges%"
:ExecElevation
"%SystemRoot%\%winSysFolder%\WScript.exe" "%vbsGetPrivileges%" %*
exit /B
:gotPrivileges
setlocal & cd /d %~dp0
if '%1'=='ELEV' (del "%vbsGetPrivileges%" 1>nul 2>nul & shift /1)
::::::::::::::::::::::::::::
::START
::::::::::::::::::::::::::::
REM Run shell as admin (example) - put here code as you like
@echo off
@echo --------------------------------
@echo BaiduProtect.exe檢測中
@echo --------------------------------
@set set "var=" >nul 2>nul
@for /f "skip=1 delims=" %%a in ('wmic process where "name='BaiduProtect.exe'" get ExecutablePath') do (
if not defined var set "var=%%~dpa"
)
@set "var=%var:~,-1%" >nul 2>nul
:loop
@tasklist | find /i "BaiduProtect.exe" >nul 2>nul
@if errorlevel 1 (echo 未發(fā)現(xiàn)BaiduProtect.exe
) else (
echo =========================================
echo 檢測到阻止助手運(yùn)行相關(guān)組件
echo 請根據(jù)彈窗進(jìn)行卸載！
echo 必須??！卸載??！
echo =========================================
start "" "%var%\uninst.exe"
for /l %%i in (5,-1,0) do (
cls
echo ============================================
echo 倒計時%%i后將再次檢測是否有該程序
echo 如未卸載，將再次彈出卸載程序。
echo 請一定一定一定要卸載！
echo ============================================
ping 127.1 -n 2 >nul
)
goto loop
)
@sc delete bd0001
@sc delete bd0002
@sc delete bd0003
@sc delete bd0004
@echo =============================================
@echo 操作已完成，請重啟電腦后再打開助手進(jìn)行操作
@echo =============================================
@echo 一定要重啟電腦！否則依然有提示
@echo =============================================
@echo 如還有問題請聯(lián)系版主或蠢灰
@echo =============================================
@echo. & pause
2、點擊【文件】--【另存為】；
3、將 保存類型修改為“所有文件”，然后將文件名修改為 x.bat ，如“修復(fù).bat”點擊保存；
4、此時我們在 修改.bat 文件上單擊右鍵，選擇【以管理員身份運(yùn)行】等待修復(fù)完成后重啟一次電腦即可修復(fù)問題！
如果是win10用戶請務(wù)必點擊重啟按鈕，關(guān)機(jī)再開機(jī)無效！win10的關(guān)機(jī)默認(rèn)是快速休眠，所有進(jìn)程后臺還是會有。
以上便是騰訊手游助手：檢測到不兼容百度bd0001 的解決方法，有遇到該故障的用戶快去試試吧~
相關(guān)文章：
騰訊手游助手玩刺激戰(zhàn)場全軍出擊鍵位或鼠標(biāo)錯亂失效的解決方法